151 lines
4.6 KiB
Nix
151 lines
4.6 KiB
Nix
{
|
|
description = "Syndicate utilities";
|
|
|
|
inputs.nixpkgs.url = "github:NixOS/nixpkgs/release-22.05";
|
|
inputs.rust = {
|
|
url = "github:oxalica/rust-overlay";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
|
|
outputs = { self, nixpkgs, rust }: {
|
|
lib = nixpkgs.lib.extend (import ./lib.nix);
|
|
|
|
overlays.default = final: prev:
|
|
let
|
|
rust' =
|
|
(prev.extend rust.overlays.default).rust-bin.nightly.latest.default;
|
|
in {
|
|
inherit (self) lib;
|
|
|
|
nimPackages = prev.nimPackages.overrideScope' (final': prev': {
|
|
preserves = final'.callPackage ./packages/preserves-nim { };
|
|
syndicate = final'.callPackage ./packages/syndicate-nim { };
|
|
syndicate_utils =
|
|
final'.callPackage ./packages/syndicate_utils-nim { };
|
|
xdg_open_ng = final'.callPackage ./packages/xdg_open_ng { };
|
|
});
|
|
|
|
python3Packages = prev.python3Packages.override {
|
|
overrides = final': prev': {
|
|
preserves = final'.callPackage ./packages/preserves-py { };
|
|
syndicate = final'.callPackage ./packages/syndicate-py { };
|
|
};
|
|
};
|
|
|
|
preserves-tools =
|
|
final.callPackage ./packages/preserves-tools { rust = rust'; };
|
|
|
|
squeak = final.callPackage ./packages/squeak { };
|
|
squeaker = final.python3Packages.callPackage ./packages/squeaker { };
|
|
|
|
syndicate-server =
|
|
final.callPackage ./packages/syndicate-server { rust = rust'; };
|
|
|
|
synit-pid1 = final.callPackage ./packages/synit-pid1 { rust = rust'; };
|
|
};
|
|
|
|
legacyPackages =
|
|
self.lib.mapAttrs (system: pkgs: pkgs.extend self.overlays.default) {
|
|
inherit (nixpkgs.legacyPackages) i686-linux x86_64-linux;
|
|
};
|
|
|
|
packages = self.lib.mapAttrs (system: pkgs:
|
|
with pkgs; {
|
|
inherit preserves-tools squeak squeaker syndicate-server;
|
|
inherit (nimPackages) syndicate_utils xdg_open_ng;
|
|
preserves-nim = nimPackages.preserves;
|
|
preserves-py = python3Packages.preserves;
|
|
syndicate-nim = nimPackages.syndicate;
|
|
syndicate-py = python3Packages.syndicate;
|
|
}) self.legacyPackages;
|
|
|
|
nixosModules = {
|
|
default = self.nixosModules.syndicate-server;
|
|
|
|
syndicate-server =
|
|
# A little hack to apply our overlay to this module only.
|
|
{ config, lib, pkgs, ... }:
|
|
(import ./nixos/syndicate-server.nix) {
|
|
inherit config lib;
|
|
pkgs = pkgs.extend self.overlays.default;
|
|
};
|
|
|
|
synit.imports = [
|
|
./nixos/modules/system/boot/stage-1.nix
|
|
./nixos/modules/system/boot/stage-2.nix
|
|
./nixos/modules/system/boot/synit.nix
|
|
];
|
|
|
|
};
|
|
|
|
devShells = self.lib.mapAttrs (system: pkgs:
|
|
with pkgs; {
|
|
default =
|
|
mkShell { packages = builtins.attrValues self.packages.${system}; };
|
|
}) self.legacyPackages;
|
|
|
|
checks = self.lib.mapAttrs (system: pkgs':
|
|
with import (nixpkgs + "/nixos/lib/testing-python.nix") {
|
|
inherit system;
|
|
pkgs = pkgs';
|
|
}; {
|
|
|
|
http = simpleTest {
|
|
nodes.machine = { config, pkgs, ... }: {
|
|
imports = [ self.nixosModules.syndicate-server ];
|
|
|
|
nixpkgs.pkgs = pkgs';
|
|
|
|
services.syndicate.http = {
|
|
enable = true;
|
|
user = "nobody";
|
|
config = [
|
|
(pkgs.writeText "http.pr" ''
|
|
<require-service <daemon http_translator>>
|
|
|
|
<daemon http_translator {
|
|
argv: [ "${pkgs.nimPackages.syndicate_utils}/bin/http_translator" ]
|
|
protocol: text/syndicate
|
|
}>
|
|
|
|
let ?other = dataspace
|
|
$other [
|
|
? <http ?handle GET ?headers ?path ?body> [
|
|
<http $handle 200 {} "Hello world!">
|
|
]
|
|
]
|
|
|
|
? <service-object <daemon http_translator> ?cap> $cap [
|
|
<listen 8888>
|
|
<handler #{GET} [ "greeting" ] $other>
|
|
]
|
|
'')
|
|
];
|
|
};
|
|
|
|
};
|
|
testScript = ''
|
|
machine.wait_for_job("syndicate-http")
|
|
machine.wait_for_open_port(8888)
|
|
machine.succeed("curl --fail http://localhost:8888/greeting")
|
|
'';
|
|
};
|
|
|
|
synit = simpleTest {
|
|
nodes.machine = {
|
|
imports = [
|
|
self.nixosModules.synit
|
|
];
|
|
|
|
nixpkgs.pkgs = pkgs';
|
|
};
|
|
testScript = ''
|
|
start_all()
|
|
machine.wait_for_unit("foo.service")
|
|
'';
|
|
};
|
|
|
|
}) { inherit (self.legacyPackages) x86_64-linux; };
|
|
};
|
|
}
|