syndicate-flake/nixos/modules/synit/boot/stage-2.nix

{ config, lib, pkgs, ... }:

{
  options.synit.logProgram = lib.mkOption {
    type = lib.types.str;
    default = pkgs.writeScript "synit-log" ''
        #!${pkgs.execline}/bin/execlineb -P
        foreground { ${pkgs.coreutils}/bin/mkdir -p /var/log/synit }
        ${pkgs.s6}/bin/s6-log t /var/log/synit
      '';
      defaultText = "s6-log";
  };

  config = {

    system.build.bootStage2 = lib.mkForce (pkgs.substituteAll {
      src = ./stage-2-init.sh;
      shellDebug = "${pkgs.bashInteractive}/bin/bash";
      shell = "${pkgs.bash}/bin/bash";
      isExecutable = true;
      inherit (config.boot) readOnlyNixStore;
      inherit (config.system.build) earlyMountScript;
      path = lib.makeBinPath [ pkgs.busybox pkgs.eudev pkgs.mdevd pkgs.util-linux ];
      inherit (pkgs) eudev;
      synit_pid1 = "${pkgs.synit-pid1}/bin/synit-pid1";
      inherit (config.synit) logProgram;
      syndicate_server = "${pkgs.syndicate-server}/bin/syndicate-server";

      postBootCommands = pkgs.writeText "local-cmds" ''
        ${config.boot.postBootCommands}
        ${config.powerManagement.powerUpCommands}
      '';

    });

  };
}