? <machine-dataspace ?machine> [
  $machine ? <interface ?ifname _ wireless _ _ _ _> [
    $config [
      <require-service <daemon <wpa_supplicant $ifname>>>
      <depends-on <daemon <wifi-daemon $ifname>> <service-state <daemon <wpa_supplicant $ifname>> up>>
      <require-service <daemon <wifi-daemon $ifname>>>
    ]
  ]

  $machine ? <interface ?ifname _ wireless up up carrier _> [
    $config <configure-interface $ifname <dhcp>>
  ]

  $config ? <user-setting <?s <selected-wifi-network _ _ _>>> [ $machine += $s ]
]

? <run-service <daemon <wifi-daemon ?ifname>>> [
  <daemon <wifi-daemon $ifname> {
    argv: "/usr/lib/synit/wifi-daemon"
    protocol: application/syndicate
  }>

  ? <machine-dataspace ?machine> [
    ? <service-object <daemon <wifi-daemon $ifname>> ?cap> [
      $cap {
        machine: $machine
        ifname: $ifname
      }
    ]
  ]
]

? <run-service <daemon <wpa_supplicant ?ifname>>> [
  <daemon <wpa_supplicant $ifname> [
    "wpa_supplicant" "-Dnl80211,wext" "-C/run/wpa_supplicant" "-i" $ifname
  ]>
]