forked from syndicate-lang/marketplace-ssh-2014
65 lines
1.9 KiB
Racket
65 lines
1.9 KiB
Racket
#lang racket/base
|
|
|
|
;; Provide AES CTR mode, since OpenSSL's EVP support for AES CTR mode
|
|
;; is still ifdef'd out.
|
|
|
|
(provide start-aes-ctr
|
|
aes-ctr-process!)
|
|
|
|
(require ffi/unsafe)
|
|
(require ffi/unsafe/define)
|
|
(require openssl/libcrypto)
|
|
|
|
(define _AES_KEY-pointer _pointer)
|
|
|
|
(define AES_BLOCK_SIZE 16)
|
|
(define sizeof-AES_KEY 244) ;; TODO: figure out a good way to get this
|
|
;; from the header file or the library
|
|
;; itself
|
|
|
|
(define-ffi-definer define-crypto libcrypto
|
|
#:default-make-fail make-not-available)
|
|
|
|
(define-crypto AES_set_encrypt_key (_fun _pointer _int _AES_KEY-pointer -> _int))
|
|
;;(define-crypto AES_set_decrypt_key (_fun _pointer _int _AES_KEY-pointer -> _int))
|
|
|
|
(define-crypto AES_ctr128_encrypt
|
|
(_fun _pointer ;; in
|
|
_pointer ;; out
|
|
_long ;; length
|
|
_AES_KEY-pointer ;; key
|
|
_pointer ;; ivec, AES_BLOCK_SIZE bytes
|
|
_pointer ;; ecount_buf, AES_BLOCK_SIZE bytes
|
|
_pointer ;; int pointer, the "num" field of the ongoing state (??)
|
|
-> _void))
|
|
|
|
(struct aes-ctr-state (key ivec ecount num) #:transparent)
|
|
|
|
(define (start-aes-ctr key initialization-vector)
|
|
(let ((key-buffer (malloc sizeof-AES_KEY))
|
|
(ivec (make-bytes AES_BLOCK_SIZE))
|
|
(ecount (make-bytes AES_BLOCK_SIZE))
|
|
(num (make-bytes (ctype-sizeof _int))))
|
|
(AES_set_encrypt_key key
|
|
(* 8 (bytes-length key)) ;; measured in bits
|
|
key-buffer)
|
|
(bytes-copy! ivec 0 initialization-vector 0 AES_BLOCK_SIZE)
|
|
(bytes-fill! ecount 0)
|
|
(bytes-fill! num 0)
|
|
(aes-ctr-state key-buffer
|
|
ivec
|
|
ecount
|
|
num)))
|
|
|
|
(define (aes-ctr-process! state input-block)
|
|
(define block-length (bytes-length input-block))
|
|
(define output-block (make-bytes block-length))
|
|
(AES_ctr128_encrypt input-block
|
|
output-block
|
|
block-length
|
|
(aes-ctr-state-key state)
|
|
(aes-ctr-state-ivec state)
|
|
(aes-ctr-state-ecount state)
|
|
(aes-ctr-state-num state))
|
|
output-block)
|