387 lines
16 KiB
Racket
387 lines
16 KiB
Racket
#lang racket/base
|
|
;; "Skeletons" describe the indexed structure of a dataspace.
|
|
;; In particular, they efficiently connect assertions to matching interests.
|
|
|
|
(provide (struct-out skeleton-interest)
|
|
make-empty-skeleton
|
|
add-interest!
|
|
remove-interest!
|
|
add-assertion!
|
|
remove-assertion!
|
|
send-assertion!
|
|
apply-projection
|
|
apply-projection-path)
|
|
|
|
(require syndicate/support/struct)
|
|
(require racket/match)
|
|
(require racket/set)
|
|
(require racket/hash)
|
|
(require racket/list)
|
|
|
|
(require "bag.rkt")
|
|
|
|
(module+ test (require rackunit))
|
|
|
|
;; A `Skeleton` is a structural guard on an assertion: essentially,
|
|
;; specification of (the outline of) its shape; its silhouette.
|
|
;; Following a skeleton's structure leads to zero or more `SkCont`s.
|
|
;;
|
|
;; Skeleton = (skeleton-node SkCont (AListof SkSelector (MutableHash SkClass SkNode)))
|
|
;; SkSelector = (skeleton-selector Nat Nat)
|
|
;; SkClass = StructType | (list-type Nat)
|
|
;;
|
|
(struct skeleton-node (continuation [edges #:mutable]) #:transparent)
|
|
(struct skeleton-selector (pop-count index) #:transparent)
|
|
(struct list-type (arity) #:transparent)
|
|
;;
|
|
;; A `SkDesc` is a single assertion silhouette, usually the
|
|
;; evaluation-result of `desc->skeleton-stx` from `pattern.rkt`.
|
|
;;
|
|
;; A `SkCont` is a *skeleton continuation*, a collection of "next
|
|
;; steps" after a `Skeleton` has matched the general outline of an
|
|
;; assertion.
|
|
;;
|
|
;; INVARIANT: At each level, the caches correspond to the
|
|
;; appropriately filtered and projected contents of the dataspace
|
|
;; containing the structures.
|
|
;;
|
|
;; SkCont = (skeleton-continuation
|
|
;; (MutableSet Assertion)
|
|
;; (MutableHash SkProj (MutableHash SkKey SkConst)))
|
|
;; SkConst = (skeleton-matched-constant
|
|
;; (MutableSet Assertion)
|
|
;; (MutableHash SkProj SkAcc))
|
|
;; SkAcc = (skeleton-accumulator
|
|
;; (MutableBag SkKey)
|
|
;; (MutableSeteq (... -> Any)))
|
|
;;
|
|
(struct skeleton-continuation (cache table) #:transparent)
|
|
(struct skeleton-matched-constant (cache table) #:transparent)
|
|
(struct skeleton-accumulator (cache handlers) #:transparent)
|
|
;;
|
|
;; A `SkProj` is a *skeleton projection*, a specification of loci
|
|
;; within a tree-shaped assertion to collect into a flat list.
|
|
;;
|
|
;; SkProj = (Listof (Listof Nat))
|
|
;;
|
|
;; The outer list specifies elements of the flat list; the inner lists
|
|
;; specify paths via zero-indexed links to child nodes in the
|
|
;; tree-shaped assertion being examined. A precondition for use of a
|
|
;; `SkProj` is that the assertion being examined has been checked for
|
|
;; conformance to the skeleton being projected.
|
|
;;
|
|
;; A `SkKey` is the result of running a `SkProj` over a term,
|
|
;; extracting the values at the denoted locations.
|
|
;;
|
|
;; SkKey = (Listof Any)
|
|
;;
|
|
;; Each `SkProj` in `SkCont` selects *constant* portions of the term
|
|
;; for more matching against the `SkKey`s in the table associated with
|
|
;; the `SkProj`. Each `SkProj` in `SkConst`, if any, selects
|
|
;; *variable* portions of the term to be given to the handler
|
|
;; functions in the associated `SkAcc`.
|
|
|
|
;; A `SkInterest` is a specification for an addition to or removal
|
|
;; from an existing `Skeleton`.
|
|
;;
|
|
;; SkInterest = (skeleton-interest SkDesc
|
|
;; SkProj
|
|
;; SkKey
|
|
;; SkProj
|
|
;; (... -> Any)
|
|
;; (Option ((MutableBag SkKey) -> Any)))
|
|
;;
|
|
;; The `SkDesc` gives the silhouette. The first `SkProj` is the
|
|
;; constant-portion selector, to be matched against the `SkKey`. The
|
|
;; second `SkProj` is used on matching assertions to extract the
|
|
;; variable portions, to be passed to the handler function.
|
|
;;
|
|
(struct skeleton-interest (desc
|
|
const-selector
|
|
const-value
|
|
var-selector
|
|
handler
|
|
cleanup
|
|
) #:transparent)
|
|
|
|
;;---------------------------------------------------------------------------
|
|
|
|
(define (make-empty-skeleton/cache cache)
|
|
(skeleton-node (skeleton-continuation cache
|
|
(make-hash))
|
|
'()))
|
|
|
|
(define (make-empty-skeleton)
|
|
(make-empty-skeleton/cache (mutable-set)))
|
|
|
|
(define (skcont-add! c i)
|
|
(match-define (skeleton-interest _desc cs cv vs h _cleanup) i)
|
|
(define (make-matched-constant)
|
|
(skeleton-matched-constant (for/mutable-set [(a (skeleton-continuation-cache c))
|
|
#:when (equal? (apply-projection a cs) cv)]
|
|
a)
|
|
(make-hash)))
|
|
(define cvt (hash-ref! (skeleton-continuation-table c) cs make-hash))
|
|
(define sc (hash-ref! cvt cv make-matched-constant))
|
|
(define (make-accumulator)
|
|
(define cache (make-bag))
|
|
(for [(a (skeleton-matched-constant-cache sc))]
|
|
(define vars (apply-projection a vs))
|
|
(bag-change! cache vars 1))
|
|
(skeleton-accumulator cache (mutable-seteq)))
|
|
(define acc (hash-ref! (skeleton-matched-constant-table sc) vs make-accumulator))
|
|
(set-add! (skeleton-accumulator-handlers acc) h)
|
|
(for [(vars (in-bag (skeleton-accumulator-cache acc)))] (apply h '+ vars)))
|
|
|
|
(define (skcont-remove! c i)
|
|
(match-define (skeleton-interest _desc cs cv vs h cleanup) i)
|
|
(define cvt (hash-ref (skeleton-continuation-table c) cs #f))
|
|
(when cvt
|
|
(define sc (hash-ref cvt cv #f))
|
|
(when sc
|
|
(define acc (hash-ref (skeleton-matched-constant-table sc) vs #f))
|
|
(when acc
|
|
(when (and cleanup (set-member? (skeleton-accumulator-handlers acc) h))
|
|
(cleanup (skeleton-accumulator-cache acc)))
|
|
(set-remove! (skeleton-accumulator-handlers acc) h)
|
|
(when (set-empty? (skeleton-accumulator-handlers acc))
|
|
(hash-remove! (skeleton-matched-constant-table sc) vs)))
|
|
(when (hash-empty? (skeleton-matched-constant-table sc))
|
|
(hash-remove! cvt cv)))
|
|
(when (hash-empty? cvt)
|
|
(hash-remove! (skeleton-continuation-table c) cs))))
|
|
|
|
(define (term-matches-class? term class)
|
|
(cond
|
|
[(list-type? class) (and (list? term) (= (length term) (list-type-arity class)))]
|
|
[(struct-type? class) (and (non-object-struct? term) (eq? (struct->struct-type term) class))]
|
|
[else (error 'term-matches-class? "Invalid class: ~v" class)]))
|
|
|
|
(define (subterm-matches-class? term path class)
|
|
(term-matches-class? (apply-projection-path term path) class))
|
|
|
|
(define (update-path path pop-count index)
|
|
(append (drop-right path pop-count) (list index)))
|
|
|
|
(define (extend-skeleton! sk desc)
|
|
(define (walk-node! path sk pop-count index desc)
|
|
(match desc
|
|
[(list class-desc pieces ...)
|
|
(define class
|
|
(cond [(eq? class-desc 'list) (list-type (length pieces))]
|
|
[(struct-type? class-desc) class-desc]
|
|
[else (error 'extend-skeleton! "Invalid class-desc: ~v" class-desc)]))
|
|
(define selector (skeleton-selector pop-count index))
|
|
(define table
|
|
(match (assoc selector (skeleton-node-edges sk))
|
|
[#f (let ((table (make-hash)))
|
|
(set-skeleton-node-edges! sk (cons (cons selector table) (skeleton-node-edges sk)))
|
|
table)]
|
|
[(cons _selector table) table]))
|
|
(define (make-skeleton-node-with-cache)
|
|
(define unfiltered (skeleton-continuation-cache (skeleton-node-continuation sk)))
|
|
(make-empty-skeleton/cache
|
|
(for/mutable-set [(a unfiltered) #:when (subterm-matches-class? a path class)] a)))
|
|
(define next (hash-ref! table class make-skeleton-node-with-cache))
|
|
(walk-edge! (update-path path pop-count 0) next 0 0 pieces)]
|
|
[_
|
|
(values pop-count sk)]))
|
|
(define (walk-edge! path sk pop-count index pieces)
|
|
(match pieces
|
|
['()
|
|
(values (+ pop-count 1) sk)]
|
|
[(cons p pieces)
|
|
(let-values (((pop-count sk) (walk-node! path sk pop-count index p)))
|
|
(walk-edge! (update-path path 1 (+ index 1)) sk pop-count (+ index 1) pieces))]))
|
|
(let-values (((_pop-count sk) (walk-edge! '(0) sk 0 0 (list desc))))
|
|
sk))
|
|
|
|
(define (add-interest! sk i)
|
|
(let ((sk (extend-skeleton! sk (skeleton-interest-desc i))))
|
|
(skcont-add! (skeleton-node-continuation sk) i)))
|
|
|
|
(define (remove-interest! sk i)
|
|
(let ((sk (extend-skeleton! sk (skeleton-interest-desc i))))
|
|
(skcont-remove! (skeleton-node-continuation sk) i)))
|
|
|
|
(define (skeleton-modify! sk term0 modify-skcont! modify-skconst! modify-skacc!)
|
|
(define (walk-node! sk term-stack)
|
|
(match-define (skeleton-node continuation edges) sk)
|
|
|
|
(modify-skcont! continuation term0)
|
|
(for [((constant-proj key-proj-handler) (in-hash (skeleton-continuation-table continuation)))]
|
|
(define constants (apply-projection term0 constant-proj))
|
|
(define proj-handler (hash-ref key-proj-handler constants #f))
|
|
(when proj-handler
|
|
(modify-skconst! proj-handler term0)
|
|
(for [((variable-proj acc) (in-hash (skeleton-matched-constant-table proj-handler)))]
|
|
(define variables (apply-projection term0 variable-proj))
|
|
(modify-skacc! acc variables term0))))
|
|
|
|
(for [(edge edges)]
|
|
(match-define (cons (skeleton-selector pop-count index) table) edge)
|
|
(define popped-stack (drop term-stack pop-count))
|
|
(define pieces (car popped-stack))
|
|
(define term (vector-ref pieces (+ index 1))) ;; adjust for struct identifier at beginning
|
|
(define entry (hash-ref table
|
|
(cond [(list? term) (list-type (length term))]
|
|
[(non-object-struct? term) (struct->struct-type term)]
|
|
[else #f])
|
|
#f))
|
|
(when entry
|
|
(define new-pieces
|
|
(cond [(list? term) (list->vector (cons 'list term))]
|
|
[(non-object-struct? term) (struct->vector term)]))
|
|
(walk-node! entry (cons new-pieces term-stack)))))
|
|
|
|
(walk-node! sk (list (vector 'list term0))))
|
|
|
|
(define (add-term-to-skcont! skcont term)
|
|
(set-add! (skeleton-continuation-cache skcont) term))
|
|
(define (add-term-to-skconst! skconst term)
|
|
(set-add! (skeleton-matched-constant-cache skconst) term))
|
|
(define (add-term-to-skacc! skacc vars _term)
|
|
(match (bag-change! (skeleton-accumulator-cache skacc) vars 1)
|
|
['absent->present
|
|
(for [(handler (skeleton-accumulator-handlers skacc))]
|
|
(apply handler '+ vars))]
|
|
;; 'present->absent and 'absent->absent absurd
|
|
['present->present
|
|
(void)]))
|
|
|
|
(define (add-assertion! sk term)
|
|
(skeleton-modify! sk
|
|
term
|
|
add-term-to-skcont!
|
|
add-term-to-skconst!
|
|
add-term-to-skacc!))
|
|
|
|
(define (remove-term-from-skcont! skcont term)
|
|
(set-remove! (skeleton-continuation-cache skcont) term))
|
|
(define (remove-term-from-skconst! skconst term)
|
|
(set-remove! (skeleton-matched-constant-cache skconst) term))
|
|
(define (remove-term-from-skacc! skacc vars _term)
|
|
(define cache (skeleton-accumulator-cache skacc))
|
|
(if (bag-member? cache vars)
|
|
(match (bag-change! cache vars -1)
|
|
['present->absent
|
|
(for [(handler (skeleton-accumulator-handlers skacc))]
|
|
(apply handler '- vars))]
|
|
;; 'absent->absent and 'absent->present absurd
|
|
['present->present
|
|
(void)])
|
|
(log-warning "Removing assertion not previously added: ~v" _term)))
|
|
|
|
(define (remove-assertion! sk term)
|
|
(skeleton-modify! sk
|
|
term
|
|
remove-term-from-skcont!
|
|
remove-term-from-skconst!
|
|
remove-term-from-skacc!))
|
|
|
|
(define (send-assertion! sk term)
|
|
(skeleton-modify! sk
|
|
term
|
|
void
|
|
void
|
|
(lambda (skacc vars _term)
|
|
(for [(handler (skeleton-accumulator-handlers skacc))]
|
|
(apply handler '! vars)))))
|
|
|
|
;; TODO: avoid repeated descent into `term` by factoring out prefixes of paths in `proj`
|
|
(define (apply-projection term proj)
|
|
(for/list [(path proj)]
|
|
(apply-projection-path term path)))
|
|
|
|
(define (apply-projection-path term path)
|
|
(for/fold [(term (list term))] [(index path)]
|
|
(cond [(list? term) (list-ref term index)]
|
|
[(non-object-struct? term) (vector-ref (struct->vector term) (+ index 1))]
|
|
[else (error 'apply-projection "Term representation not supported: ~v" term)])))
|
|
|
|
;;---------------------------------------------------------------------------
|
|
|
|
(module+ test
|
|
(struct a (x y) #:transparent)
|
|
(struct b (v) #:transparent)
|
|
(struct c (v) #:transparent)
|
|
(struct d (x y z) #:transparent)
|
|
|
|
(define sk
|
|
(make-empty-skeleton/cache (mutable-set (a (b 'bee) (b 'cat))
|
|
(a (b 'foo) (c 'bar))
|
|
(a (b 'foo) (c 'BAR))
|
|
(a (c 'bar) (b 'foo))
|
|
(a (c 'dog) (c 'fox))
|
|
(d (b 'DBX) (b 'DBY) (b 'DBZ))
|
|
(d (c 'DCX) (c 'DCY) (c 'DCZ))
|
|
(b 'zot)
|
|
123)))
|
|
|
|
(define i1
|
|
(skeleton-interest (list struct:a (list struct:b #f) #f)
|
|
'((0 0 0))
|
|
'(foo)
|
|
'((0 1))
|
|
(lambda (op . bindings)
|
|
(printf "xAB HANDLER: ~v ~v\n" op bindings))
|
|
(lambda (vars)
|
|
(printf "xAB CLEANUP: ~v\n" vars))))
|
|
|
|
(add-interest! sk i1)
|
|
|
|
(void (extend-skeleton! sk (list struct:a (list struct:b #f) #f)))
|
|
(void (extend-skeleton! sk (list struct:a #f (list struct:c #f))))
|
|
(void (extend-skeleton! sk (list struct:a #f (list struct:c (list struct:b #f)))))
|
|
(void (extend-skeleton! sk (list struct:a #f #f)))
|
|
(void (extend-skeleton! sk (list struct:c #f)))
|
|
(void (extend-skeleton! sk (list struct:b #f)))
|
|
(void (extend-skeleton! sk (list struct:d (list struct:b #f) #f (list struct:b #f))))
|
|
(void (extend-skeleton! sk (list struct:d (list struct:b #f) #f (list struct:c #f))))
|
|
(void (extend-skeleton! sk (list struct:d (list struct:c #f) #f (list struct:b #f))))
|
|
(void (extend-skeleton! sk (list struct:d (list struct:c #f) #f (list struct:c #f))))
|
|
(check-eq? sk (extend-skeleton! sk #f))
|
|
|
|
(add-interest! sk
|
|
(skeleton-interest (list struct:d (list struct:b #f) #f (list struct:c #f))
|
|
'((0 2 0))
|
|
'(DCZ)
|
|
'((0) (0 0) (0 0 0) (0 1))
|
|
(lambda (op . bindings)
|
|
(printf "DBC HANDLER: ~v ~v\n" op bindings))
|
|
(lambda (vars)
|
|
(printf "DBC CLEANUP: ~v\n" vars))))
|
|
|
|
(remove-assertion! sk (a (b 'foo) (c 'bar)))
|
|
(remove-assertion! sk (d (b 'B1) (b 'DBY) (c 'DCZ)))
|
|
(add-assertion! sk (d (b 'B1) (b 'DBY) (c 'DCZ)))
|
|
(add-assertion! sk (d (b 'BX) (b 'DBY) (c 'DCZ)))
|
|
(add-assertion! sk (d (b 'B1) (b 'DBY) (c 'CX)))
|
|
(add-assertion! sk (d (b 'B1) (b 'DBY) (c 'DCZ)))
|
|
(add-assertion! sk (d (b 'BX) (b 'DBY) (c 'DCZ)))
|
|
(add-assertion! sk (d (b 'B1) (b 'DBY) (c 'CX)))
|
|
|
|
(add-interest! sk
|
|
(skeleton-interest (list struct:d #f (list struct:b #f) #f)
|
|
'((0 1 0))
|
|
'(DBY)
|
|
'((0 0) (0 2))
|
|
(lambda (op . bindings)
|
|
(printf "xDB HANDLER: ~v ~v\n" op bindings))
|
|
(lambda (vars)
|
|
(printf "xDB CLEANUP: ~v\n" vars))))
|
|
|
|
(send-assertion! sk (d (b 'BX) (b 'DBY) (c 'DCZ)))
|
|
(send-assertion! sk (d (b 'BX) (b 'DBY) (c 'DCZ)))
|
|
|
|
(remove-assertion! sk (d (b 'B1) (b 'DBY) (c 'DCZ)))
|
|
(remove-assertion! sk (d (b 'BX) (b 'DBY) (c 'DCZ)))
|
|
(remove-assertion! sk (d (b 'B1) (b 'DBY) (c 'CX)))
|
|
(remove-assertion! sk (d (b 'B1) (b 'DBY) (c 'DCZ)))
|
|
(remove-assertion! sk (d (b 'BX) (b 'DBY) (c 'DCZ)))
|
|
(remove-assertion! sk (d (b 'B1) (b 'DBY) (c 'CX)))
|
|
;; sk
|
|
|
|
(remove-interest! sk i1)
|
|
)
|