# SPDX-FileCopyrightText: ☭ Emery Hemingway
# SPDX-License-Identifier: Unlicense

import std/[os, tables]
import preserves, syndicate, syndicate/[durings, relays]

proc parsePattern(pr: Value): Pattern =
  let
    dropSigil = initRecord("lit", "_".toSymbol)
    grabSigil = initRecord("lit", "?".toSymbol)
  var pr = grab(pr).toPreserves
  apply(pr) do (pr: var Value):
    if pr == dropSigil:
      pr = initRecord("_")
    elif pr == grabSigil:
      pr = initRecord("bind", initRecord("_"))
  doAssert result.fromPreserves(pr)

proc inputPatterns: seq[Pattern] =
  var args = commandLineParams()
  result.setLen(args.len)
  for i, input in args:
    try: result[i] = input.parsePreserves.parsePattern
    except ValueError:
      quit "failed to parse Preserves argument"

type DumpEntity {.final.} = ref object of Entity
  assertions: Table[Handle, seq[Value]]

proc toLine(values: seq[Value]; prefix: char): string =
  result = newStringOfCap(1024)
  let sep = getEnv("FS", " ")
  result.add(prefix)
  for v in values:
    add(result, sep)
    add(result, $v)
  add(result, '\n')

method publish(dump: DumpEntity; turn: Turn; ass: AssertionRef; h: Handle) =
  var values = ass.value.sequence
  stdout.write(values.toLine('+'))
  stdout.flushFile()
  dump.assertions[h] = values

method retract(dump: DumpEntity; turn: Turn; h: Handle) =
  var values: seq[Value]
  if dump.assertions.pop(h, values):
    stdout.write(values.toLine('-'))
    stdout.flushFile()

method message*(dump: DumpEntity; turn: Turn; ass: AssertionRef) =
  stdout.write(ass.value.sequence.toLine('!'))
  stdout.flushFile()

proc exitProc() {.noconv.} =
  stdout.write('\n')
  quit()

proc main =
  let
    patterns = inputPatterns()
    entity = DumpEntity()
  runActor("syndex_card") do (turn: Turn):
    resolveEnvironment(turn) do (turn: Turn; ds: Cap):
      for pat in patterns:
        discard observe(turn, ds, pat, entity)

setControlCHook(exitProc)
main()