syndicate_utils/src/json_socket_translator.nim

# SPDX-FileCopyrightText: ☭ 2022 Emery Hemingway
# SPDX-License-Identifier: Unlicense

import std/[asyncdispatch, asyncnet, json]
from std/nativesockets import AF_UNIX, SOCK_STREAM, Protocol
import preserves, preserves/jsonhooks, syndicate, syndicate/patterns

import ./schema/config

bootDataspace("main") do (root: Ref; turn: var Turn):
  connectStdio(root, turn)
  during(turn, root, ?JsonSocketTranslatorArguments) do (ds: Ref, socketPath: string):
    let socket = newAsyncSocket(
        domain = AF_UNIX,
        sockType = SOCK_STREAM,
        protocol = cast[Protocol](0),
        buffered = false,
      )
    waitFor connectUnix(socket, socketPath)

    let f = turn.facet
    proc processOutput(fut: Future[string]) {.gcsafe.} =
      run(f) do (turn: var Turn):
        var data = fut.read.parseJson.toPreserve
        message(turn, ds, initRecord("recv-json", data))
      socket.recvLine.addCallback(processOutput)
    socket.recvLine.addCallback(processOutput)

    onMessage(turn, ds, ?Input) do (data: Assertion):
      var js: JsonNode
      if fromPreserve(js, data):
        asyncCheck(turn, send(socket, $js & "\n"))
      else:
        writeLine(stderr, "cannot convert assertion to JSON - ", data)

runForever()