{
  description = "Syndicate utilities";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/release-22.11";
    rust = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, rust }: {
    lib = nixpkgs.lib.extend (import ./lib.nix);

    overlays.default = final: prev:
      let rust' = (prev.extend rust.overlay).rust-bin.nightly.latest.default;
      in {
        inherit (self) lib;

        acpi_actor = final.nimPackages.callPackage ./packages/acpi_actor { };

        fontconfig_actor =
          final.nimPackages.callPackage ./packages/fontconfig_actor { };

        libnotify_actor =
          final.nimPackages.callPackage ./packages/libnotify_actor { };

        nimPackages = prev.nimPackages.overrideScope' (final': prev': {
          preserves = final'.callPackage ./packages/preserves-nim { };
          syndicate = final'.callPackage ./packages/syndicate-nim { };
          syndicate_utils =
            final'.callPackage ./packages/syndicate_utils-nim { };
          xdg_open_ng = final'.callPackage ./packages/xdg_open_ng { };
        });

        python3Packages = prev.python3Packages.override {
          overrides = final': prev': {
            preserves = final'.callPackage ./packages/preserves-py { };
            syndicate = final'.callPackage ./packages/syndicate-py { };
          };
        };

        preserves-tools =
          final.callPackage ./packages/preserves-tools { rust = rust'; };

        squeak = final.callPackage ./packages/squeak { };
        squeaker = final.python3Packages.callPackage ./packages/squeaker { };

        syndicate-server =
          final.callPackage ./packages/syndicate-server { rust = rust'; };

        synit-pid1 = final.callPackage ./packages/synit-pid1 { rust = rust'; };
      };

    legacyPackages =
      self.lib.mapAttrs (system: pkgs: pkgs.extend self.overlays.default) {
        inherit (nixpkgs.legacyPackages) x86_64-linux;
      };

    packages = self.lib.mapAttrs (system: pkgs:
      with pkgs; {
        inherit fontconfig_actor libnotify_actor preserves-tools squeak squeaker
          syndicate-server;
        inherit (nimPackages) syndicate_utils xdg_open_ng;
        preserves-nim = nimPackages.preserves;
        preserves-py = python3Packages.preserves;
        syndicate-nim = nimPackages.syndicate;
        syndicate-py = python3Packages.syndicate;
      }) self.legacyPackages;

    nixosModules.default = self.nixosModules.syndicate-server;
    nixosModules.syndicate-server =
      # A little hack to apply our overlay to this module only.
      { config, lib, pkgs, ... }:
      (import ./nixos/syndicate-server.nix) {
        inherit config lib;
        pkgs = pkgs.extend self.overlays.default;
      };

    devShells = self.lib.mapAttrs (system: pkgs:
      with pkgs; {
        default =
          mkShell { packages = builtins.attrValues self.packages.${system}; };
      }) self.legacyPackages;

    checks = self.lib.mapAttrs (system: pkgs':
      with import (nixpkgs + "/nixos/lib/testing-python.nix") {
        inherit system;
        pkgs = pkgs';
      };
      {
        # nothing here
      }) { inherit (self.legacyPackages) x86_64-linux; };
  };
}