809 lines
24 KiB
Nim
809 lines
24 KiB
Nim
# SPDX-FileCopyrightText: 2021 ☭ Emery Hemingway
|
|
# SPDX-License-Identifier: Unlicense
|
|
|
|
import bigints
|
|
import std/[algorithm, base64, endians, hashes, options, sets, sequtils, streams, strutils, tables, typetraits]
|
|
|
|
from std/json import escapeJson, escapeJsonUnquoted
|
|
from std/macros import hasCustomPragma, getCustomPragmaVal
|
|
|
|
type
|
|
PreserveKind* = enum
|
|
pkBoolean, pkFloat, pkDouble, pkSignedInteger, pkBigInteger, pkString, pkByteString, pkSymbol,
|
|
pkRecord, pkSequence, pkSet, pkDictionary,
|
|
pkEmbedded
|
|
|
|
const
|
|
atomKinds* = {pkBoolean, pkFloat, pkDouble, pkSignedInteger, pkBigInteger, pkString, pkByteString, pkSymbol}
|
|
compoundKinds* = {pkRecord, pkSequence, pkSet, pkDictionary}
|
|
|
|
type
|
|
DictEntry[EmbededType] = tuple[key: PreserveGen[EmbededType], val: PreserveGen[EmbededType]]
|
|
|
|
PreserveGen*[EmbeddedType] {.acyclic.} = ref object
|
|
## Generic ``Preserve`` type before embedding.
|
|
case kind*: PreserveKind
|
|
of pkBoolean:
|
|
bool*: bool
|
|
of pkFloat:
|
|
float*: float32
|
|
of pkDouble:
|
|
double*: float64
|
|
of pkSignedInteger:
|
|
int*: BiggestInt
|
|
of pkBigInteger:
|
|
bigint*: BigInt
|
|
of pkString:
|
|
string*: string
|
|
of pkByteString:
|
|
bytes*: seq[byte]
|
|
of pkSymbol:
|
|
symbol*: string
|
|
of pkRecord:
|
|
record*: seq[PreserveGen[EmbeddedType]] # label is last
|
|
of pkSequence:
|
|
sequence*: seq[PreserveGen[EmbeddedType]]
|
|
of pkSet:
|
|
set*: seq[PreserveGen[EmbeddedType]]
|
|
# HashSet templates not hygenic enough for this type
|
|
of pkDictionary:
|
|
dict*: seq[DictEntry[EmbeddedType]]
|
|
# Tables templates not hygenic enough for this type
|
|
of pkEmbedded:
|
|
when EmbeddedType is void:
|
|
embedded*: PreserveGen[EmbeddedType]
|
|
else:
|
|
embedded*: EmbeddedType
|
|
|
|
template PreserveOf*(T: typedesc): untyped = PreserveGen[T]
|
|
## Customize ``PreserveGen`` with an embedded type.
|
|
## ```
|
|
## type MyPreserve = PreserveOf(MyEmbbededType)
|
|
## ```
|
|
|
|
type
|
|
Preserve* = PreserveOf(void)
|
|
## Type of Preserves with all embedded values
|
|
## converted to an unembedded representation.
|
|
|
|
proc `<`(x, y: string | seq[byte]): bool =
|
|
for i in 0 .. min(x.high, y.high):
|
|
if x[i] < y[i]: return true
|
|
if x[i] != y[i]: return false
|
|
x.len < y.len
|
|
|
|
proc `<`*[E](x, y: PreserveGen[E]): bool =
|
|
## Preserves have a total order over Values. Check if `x` is ordered before `y`.
|
|
if x.kind != y.kind:
|
|
if x.kind == pkSignedInteger and y.kind == pkBigInteger:
|
|
result = x.int.initBigInt < y.bigint
|
|
elif x.kind == pkBigInteger and y.kind == pkSignedInteger:
|
|
result = x.bigint < y.int.initBigInt
|
|
else:
|
|
result = x.kind < y.kind
|
|
else:
|
|
case x.kind
|
|
of pkBoolean:
|
|
result = (not x.bool) and y.bool
|
|
of pkFloat:
|
|
result = x.float < y.float
|
|
of pkDouble:
|
|
result = x.double < y.double
|
|
of pkSignedInteger:
|
|
result = x.int < y.int
|
|
of pkBigInteger:
|
|
result = x.bigint < y.bigint
|
|
of pkString:
|
|
result = x.string < y.string
|
|
of pkByteString:
|
|
result = x.bytes < y.bytes
|
|
of pkSymbol:
|
|
result = x.symbol < y.symbol
|
|
of pkRecord:
|
|
if x.record[x.record.high] < y.record[y.record.high]: return true
|
|
for i in 0..<min(x.record.high, y.record.high):
|
|
if x.record[i] < y.record[i]: return true
|
|
if x.record[i] != y.record[i]: return false
|
|
result = x.record.len < y.record.len
|
|
of pkSequence:
|
|
for i in 0..min(x.sequence.high, y.sequence.high):
|
|
if x.sequence[i] < y.sequence[i]: return true
|
|
if x.sequence[i] != y.sequence[i]: return false
|
|
result = x.sequence.len < y.sequence.len
|
|
of pkSet:
|
|
for i in 0..min(x.set.high, y.set.high):
|
|
if x.set[i] < y.set[i]: return true
|
|
if x.set[i] != y.set[i]: return false
|
|
result = x.set.len < y.set.len
|
|
of pkDictionary:
|
|
for i in 0..min(x.dict.high, y.dict.high):
|
|
if x.dict[i].key < y.dict[i].key: return true
|
|
if x.dict[i].key == y.dict[i].key:
|
|
if x.dict[i].val < y.dict[i].val: return true
|
|
if x.dict[i].val != y.dict[i].val: return false
|
|
result = x.dict.len < y.dict.len
|
|
of pkEmbedded:
|
|
when not E is void:
|
|
result = x.embedded < y.embedded
|
|
|
|
proc `==`*[E](x, y: PreserveGen[E]): bool =
|
|
## Check `x` and `y` for equivalence.
|
|
# TODO: is this necessary to define?
|
|
if x.isNil or y.isNil:
|
|
result = x.isNil and y.isNil
|
|
elif x.kind == y.kind:
|
|
case x.kind
|
|
of pkBoolean:
|
|
result = x.bool == y.bool
|
|
of pkFloat:
|
|
result = x.float == y.float
|
|
of pkDouble:
|
|
result = x.double == y.double
|
|
of pkSignedInteger:
|
|
result = x.int == y.int
|
|
of pkBigInteger:
|
|
result = x.bigint == y.bigint
|
|
of pkString:
|
|
result = x.string == y.string
|
|
of pkByteString:
|
|
result = x.bytes == y.bytes
|
|
of pkSymbol:
|
|
result = x.symbol == y.symbol
|
|
of pkRecord:
|
|
result = x.record == y.record
|
|
of pkSequence:
|
|
for i, val in x.sequence:
|
|
if y.sequence[i] != val: return false
|
|
result = true
|
|
of pkSet:
|
|
result = x.set == y.set
|
|
of pkDictionary:
|
|
result = x.dict == y.dict
|
|
of pkEmbedded:
|
|
result = x.embedded == y.embedded
|
|
|
|
proc hash*[E](prs: PreserveGen[E]): Hash =
|
|
## Produce a `Hash` of `prs` for use with a `HashSet` or `Table`.
|
|
type Value = PreserveGen[E]
|
|
var h = hash(prs.kind.int)
|
|
case prs.kind
|
|
of pkBoolean:
|
|
h = h !& hash(prs.bool)
|
|
of pkFloat:
|
|
h = h !& hash(prs.float)
|
|
of pkDouble:
|
|
h = h !& hash(prs.double)
|
|
of pkSignedInteger:
|
|
h = h !& hash(prs.int)
|
|
of pkBigInteger:
|
|
h = h !& hash(prs.bigint.flags)
|
|
h = h !& hash(prs.bigint)
|
|
of pkString:
|
|
h = h !& hash(prs.string)
|
|
of pkByteString:
|
|
h = h !& hash(prs.bytes)
|
|
of pkSymbol:
|
|
h = h !& hash(prs.symbol)
|
|
of pkRecord:
|
|
for val in prs.record:
|
|
h = h !& hash(val)
|
|
of pkSequence:
|
|
for val in prs.sequence:
|
|
h = h !& hash(val)
|
|
of pkSet:
|
|
for val in prs.set.items:
|
|
h = h !& hash(val)
|
|
of pkDictionary:
|
|
for (key, val) in prs.dict.items:
|
|
h = h !& hash(key) !& hash(val)
|
|
of pkEmbedded:
|
|
when not E is void:
|
|
h = h !& hash(prs.embedded)
|
|
!$h
|
|
|
|
proc `[]`*(prs: Preserve; i: int): Preserve =
|
|
## Select an indexed value from `prs`.
|
|
## Only valid for records and sequences.
|
|
case prs.kind
|
|
of pkRecord: prs.record[i]
|
|
of pkSequence: prs.sequence[i]
|
|
else:
|
|
raise newException(ValueError, "`[]` is not valid for " & $prs.kind)
|
|
|
|
proc incl*[E](prs: var PreserveGen[E]; key: PreserveGen[E]) =
|
|
## Include `key` in the Preserves set `prs`.
|
|
for i in 0..prs.set.high:
|
|
if key < prs.set[i]:
|
|
insert(prs.set, [key], i)
|
|
return
|
|
prs.set.add(key)
|
|
|
|
proc excl*[E](prs: var PreserveGen[E]; key: PreserveGen[E]) =
|
|
## Exclude `key` from the Preserves set `prs`.
|
|
for i in 0..prs.set.high:
|
|
if prs.set[i] == key:
|
|
delete(prs.set, i, i)
|
|
break
|
|
|
|
proc `[]`*[E](prs: var PreserveGen[E]; key: PreserveGen[E]): PreserveGen[E] =
|
|
## Select a value by `key` from the Preserves dictionary `prs`.
|
|
for (k, v) in prs.dict.items:
|
|
if k == key: return v
|
|
raise newException(KeyError, "value not in Preserves dictionary")
|
|
|
|
proc `[]=`*[E](prs: var PreserveGen[E]; key, val: PreserveGen[E]) =
|
|
## Insert `val` by `key` in the Preserves dictionary `prs`.
|
|
for i in 0..prs.dict.high:
|
|
if key < prs.dict[i].key:
|
|
insert(prs.dict, [(key, val, )], i)
|
|
return
|
|
elif key == prs.dict[i].key:
|
|
prs.dict[i].val = val
|
|
return
|
|
prs.dict.add((key, val, ))
|
|
|
|
proc symbol*(s: string; E = void): PreserveGen[E] {.inline.} =
|
|
## Create a Preserves symbol value.
|
|
PreserveGen[E](kind: pkSymbol, symbol: s)
|
|
|
|
proc initRecord*[E](label: PreserveGen[E]; args: varargs[PreserveGen[E]]): PreserveGen[E] =
|
|
## Create a Preserves record value.
|
|
result = Preserve(kind: pkRecord,
|
|
record: newSeqOfCap[Preserve](1+args.len))
|
|
for arg in args:
|
|
result.record.add(arg)
|
|
result.record.add(label)
|
|
|
|
proc initRecord*(label: string; args: varargs[Preserve, toPreserve]): Preserve =
|
|
## Convert ``label`` to a symbol and create a new record.
|
|
runnableExamples:
|
|
assert($initRecord("foo", 1, 2.0) == "<foo 1 2.0f>")
|
|
initRecord(symbol(label), args)
|
|
|
|
proc initSet*(E = void): PreserveGen[E] = PreserveGen[E](kind: pkSet)
|
|
## Create a Preserves set value.
|
|
|
|
proc initDictionary*(E = void): PreserveGen[E] = PreserveGen[E](kind: pkDictionary)
|
|
## Create a Preserves dictionary value.
|
|
|
|
proc len*[E](prs: PreserveGen[E]): int =
|
|
## Return the shallow count of values in ``prs``, that is the number of
|
|
## fields in a record, items in a sequence, items in a set, or key-value pairs
|
|
## in a dictionary.
|
|
case prs.kind
|
|
of pkRecord: prs.record.len.pred
|
|
of pkSequence: prs.sequence.len
|
|
of pkSet: prs.set.len
|
|
of pkDictionary: prs.dict.len
|
|
else: 0
|
|
|
|
iterator items*[E](prs: PreserveGen[E]): PreserveGen[E] =
|
|
## Shallow iterator over `prs`, yield the fields in a record,
|
|
## the items of a sequence, the items of a set, or the pairs
|
|
## of a dictionary.
|
|
case prs.kind
|
|
of pkRecord:
|
|
for i in 0..prs.record.high.pred:
|
|
yield prs.record[i]
|
|
of pkSequence:
|
|
for e in prs.sequence.items: yield e
|
|
of pkSet:
|
|
for e in prs.set.items: yield e
|
|
of pkDictionary:
|
|
for (k, v) in prs.dict.items:
|
|
yield k # key can be an arbitrary Preserve
|
|
yield v
|
|
else: discard
|
|
|
|
proc isFalse*[E](prs: PreserveGen[E]): bool =
|
|
## Check if ``prs`` is equivalent to the zero-initialized ``Preserve``.
|
|
prs.kind == pkBoolean and prs.bool == false
|
|
|
|
proc isSymbol*[E](prs: PreserveGen[E]; sym: string): bool =
|
|
## Check if `prs` is a Preserves symbol.
|
|
(prs.kind == pkSymbol) and (prs.symbol == sym)
|
|
|
|
proc isRecord*[E](prs: PreserveGen[E]): bool =
|
|
## Check if `prs` is a Preserves record.
|
|
if prs.kind == pkRecord:
|
|
result = true
|
|
assert(prs.record.len > 0)
|
|
|
|
proc isDictionary*[E](prs: PreserveGen[E]): bool =
|
|
## Check if `prs` is a Preserves dictionary.
|
|
prs.kind == pkDictionary
|
|
|
|
proc label*[E](prs: PreserveGen[E]): PreserveGen[E] {.inline.} =
|
|
## Return the label of record value.
|
|
prs.record[prs.record.high]
|
|
|
|
proc arity*[E](prs: PreserveGen[E]): int {.inline.} =
|
|
## Return the number of fields in record `prs`.
|
|
pred(prs.record.len)
|
|
|
|
proc fields*[E](prs: PreserveGen[E]): seq[PreserveGen[E]] {.inline.} =
|
|
## Return the fields of a record value.
|
|
prs.record[0..prs.record.high.pred]
|
|
|
|
iterator fields*[E](prs: PreserveGen[E]): PreserveGen[E] =
|
|
## Iterate the fields of a record value.
|
|
for i in 0..<prs.record.high: yield prs.record[i]
|
|
|
|
proc writeVarint(s: Stream; n: int) =
|
|
var n = n
|
|
while true:
|
|
let c = int8(n and 0x7f)
|
|
n = n shr 7
|
|
if n == 0:
|
|
s.write((char)c.char)
|
|
break
|
|
else:
|
|
s.write((char)c or 0x80)
|
|
|
|
proc readVarint(s: Stream): int =
|
|
var shift: int
|
|
while shift < (9*8):
|
|
let c = s.readChar.int
|
|
result = result or ((c and 0x7f) shl shift)
|
|
if (c and 0x80) == 0:
|
|
break
|
|
shift.inc 7
|
|
|
|
proc write*[E](str: Stream; prs: PreserveGen[E]) =
|
|
## Write the binary-encoding of a Preserves value to a stream.
|
|
case prs.kind:
|
|
of pkBoolean:
|
|
case prs.bool
|
|
of false: str.write(0x80'u8)
|
|
of true: str.write(0x81'u8)
|
|
of pkFloat:
|
|
str.write(0x82'u8)
|
|
when system.cpuEndian == bigEndian:
|
|
str.write(prs.float)
|
|
else:
|
|
var be: float32
|
|
swapEndian32(be.addr, prs.float.unsafeAddr)
|
|
str.write(be)
|
|
of pkDouble:
|
|
str.write(0x83'u8)
|
|
when system.cpuEndian == bigEndian:
|
|
str.write(prs.double)
|
|
else:
|
|
var be: float64
|
|
swapEndian64(be.addr, prs.double.unsafeAddr)
|
|
str.write(be)
|
|
of pkSignedInteger:
|
|
if (-3 <= prs.int) and (prs.int <= 12):
|
|
str.write(0x90'i8 or int8(if prs.int < 0: prs.int + 16 else: prs.int))
|
|
else:
|
|
var bitCount = 1'u8
|
|
if prs.int < 0:
|
|
while ((not prs.int) shr bitCount) != 0:
|
|
inc(bitCount)
|
|
else:
|
|
while (prs.int shr bitCount) != 0:
|
|
inc(bitCount)
|
|
var byteCount = (bitCount + 8) div 8
|
|
str.write(0xa0'u8 or (byteCount - 1))
|
|
proc write(n: uint8; i: BiggestInt) =
|
|
if n > 0:
|
|
write(n.pred, i shr 8)
|
|
str.write(i.uint8)
|
|
write(byteCount, prs.int)
|
|
of pkBigInteger:
|
|
doAssert(Negative notin prs.bigint.flags, "negative big integers not implemented")
|
|
var bytes = newSeqOfCap[uint8](prs.bigint.limbs.len * 4)
|
|
var begun = false
|
|
for i in countdown(prs.bigint.limbs.high, 0):
|
|
let limb = prs.bigint.limbs[i]
|
|
for j in countdown(24, 0, 8):
|
|
let b = uint8(limb shr j)
|
|
begun = begun or (b != 0)
|
|
if begun:
|
|
bytes.add(b)
|
|
if bytes.len <= 16:
|
|
str.write(0xa0'u8 or bytes.high.uint8)
|
|
else:
|
|
str.write(0xb0'u8)
|
|
str.writeVarint(bytes.len)
|
|
str.write(cast[string](bytes))
|
|
of pkString:
|
|
str.write(0xb1'u8)
|
|
str.writeVarint(prs.string.len)
|
|
str.write(prs.string)
|
|
of pkByteString:
|
|
str.write(0xb2'u8)
|
|
str.writeVarint(prs.bytes.len)
|
|
str.write(cast[string](prs.bytes))
|
|
of pkSymbol:
|
|
str.write(0xb3'u8)
|
|
str.writeVarint(prs.symbol.len)
|
|
str.write(prs.symbol)
|
|
of pkRecord:
|
|
assert(prs.record.len > 0)
|
|
str.write(0xb4'u8)
|
|
str.write(prs.record[prs.record.high])
|
|
for i in 0..<prs.record.high:
|
|
str.write(prs.record[i])
|
|
str.write(0x84'u8)
|
|
of pkSequence:
|
|
str.write(0xb5'u8)
|
|
for e in prs.sequence:
|
|
str.write(e)
|
|
str.write(0x84'u8)
|
|
of pkSet:
|
|
str.write(0xb6'u8)
|
|
for val in prs.set.items:
|
|
str.write(val)
|
|
str.write(0x84'u8)
|
|
of pkDictionary:
|
|
str.write(0xb7'u8)
|
|
for (key, value) in prs.dict.items:
|
|
str.write(key)
|
|
str.write(value)
|
|
str.write(0x84'u8)
|
|
of pkEmbedded:
|
|
str.write(0x86'u8)
|
|
when E is void:
|
|
str.write(0x80'u8)
|
|
else:
|
|
str.write(prs.embedded.toPreserve)
|
|
|
|
proc encode*[E](prs: PreserveGen[E]): string =
|
|
## Return the binary-encoding of a Preserves value.
|
|
let s = newStringStream()
|
|
s.write prs
|
|
s.setPosition 0
|
|
result = s.readAll
|
|
|
|
proc decodePreserves*(s: Stream; E = void): PreserveGen[E] =
|
|
## Decode a Preserves value from a binary-encoded stream.
|
|
## ``E`` is the Nim type of embedded values where ``void``
|
|
## selects a ``Preserve`` representation.
|
|
type Value = PreserveGen[E]
|
|
proc assertStream(check: bool) =
|
|
if not check:
|
|
raise newException(ValueError, "invalid Preserves stream")
|
|
const endMarker = 0x84
|
|
let tag = s.readUint8()
|
|
case tag
|
|
of 0x80: result = Value(kind: pkBoolean, bool: false)
|
|
of 0x81: result = Value(kind: pkBoolean, bool: true)
|
|
of 0x82:
|
|
when system.cpuEndian == bigEndian:
|
|
result = Value(kind: pkFloat, float: s.readFloat32())
|
|
else:
|
|
result = Value(kind: pkFloat)
|
|
var be = s.readFloat32()
|
|
swapEndian32(result.float.addr, be.addr)
|
|
of 0x83:
|
|
when system.cpuEndian == bigEndian:
|
|
result = Value(kind: pkDouble, double: s.readFloat64())
|
|
else:
|
|
result = Value(kind: pkDouble)
|
|
var be = s.readFloat64()
|
|
swapEndian64(result.double.addr, be.addr)
|
|
of 0x86:
|
|
result = Value(kind: pkEmbedded, embedded: decodePreserves(s, E))
|
|
of 0xb1:
|
|
result = Value(kind: pkString)
|
|
let len = s.readVarint()
|
|
result.string = s.readStr(len)
|
|
of 0xb2:
|
|
result = Value(kind: pkByteString)
|
|
let len = s.readVarint()
|
|
result.bytes = cast[seq[byte]](s.readStr(len))
|
|
of 0xb3:
|
|
let len = s.readVarint()
|
|
result = Value(kind: pkSymbol, symbol: s.readStr(len))
|
|
of 0xb4:
|
|
result = Value(kind: pkRecord)
|
|
var label = decodePreserves(s, E)
|
|
while s.peekUint8() != endMarker:
|
|
result.record.add decodePreserves(s, E)
|
|
result.record.add(move label)
|
|
discard s.readUint8()
|
|
of 0xb5:
|
|
result = Value(kind: pkSequence)
|
|
while s.peekUint8() != endMarker:
|
|
result.sequence.add decodePreserves(s, E)
|
|
discard s.readUint8()
|
|
of 0xb6:
|
|
result = Value(kind: pkSet)
|
|
while s.peekUint8() != endMarker:
|
|
incl(result, decodePreserves(s, E))
|
|
discard s.readUint8()
|
|
of 0xb7:
|
|
result = Value(kind: pkDictionary)
|
|
while s.peekUint8() != endMarker:
|
|
result[decodePreserves(s, E)] = decodePreserves(s, E)
|
|
discard s.readUint8()
|
|
of 0xb0:
|
|
let len = s.readVarint()
|
|
result = Value(kind: pkBigInteger, bigint: initBigint 0)
|
|
for _ in 1..len:
|
|
result.bigint = (result.bigint shl 8) + s.readUint8().int32
|
|
of endMarker:
|
|
assertStream(false)
|
|
else:
|
|
case 0xf0 and tag
|
|
of 0x90:
|
|
var n = tag.BiggestInt
|
|
result = Value(kind: pkSignedInteger,
|
|
int: n - (if n > 0x9c: 0xa0 else: 0x90))
|
|
of 0xa0:
|
|
let len = (tag.int and 0x0f) + 1
|
|
if len <= 8:
|
|
result = Value(kind: pkSignedInteger, int: s.readUint8().BiggestInt)
|
|
if (result.int and 0x80) != 0: result.int.dec(0x100)
|
|
for i in 1..<len:
|
|
result.int = (result.int shl 8) or s.readUint8().BiggestInt
|
|
else:
|
|
result = Value(kind: pkBigInteger)
|
|
for i in 0..<len:
|
|
result.bigint = (result.bigint shl 8) + s.readUint8().int32
|
|
else:
|
|
assertStream(false)
|
|
|
|
proc decodePreserves*(s: string, E = void): PreserveGen[E] =
|
|
## Decode a string of binary-encoded Preserves.
|
|
s.newStringStream.decodePreserves E
|
|
|
|
proc decodePreserves*(s: seq[byte], E = void): PreserveGen[E] =
|
|
## Decode a byte-string of binary-encoded Preserves.
|
|
cast[string](s).decodePreserves E
|
|
|
|
template record*(label: string) {.pragma.}
|
|
## Serialize this object or tuple as a record. See ``toPreserve``.
|
|
|
|
template unpreservable*() {.pragma.}
|
|
## Pragma to forbid a type from being converted by ``toPreserve``.
|
|
|
|
proc toPreserve*[T](x: T; E = void): PreserveGen[E] =
|
|
## Serializes ``x`` to Preserves. Can be customized by defining
|
|
## ``toPreserveHook(x: T)`` in the calling scope.
|
|
## ``E`` is the embedded type where ``void`` returns embedded
|
|
## values as Preserves.
|
|
type Value = PreserveGen[E]
|
|
when (T is Value): result = x
|
|
elif T is E: result = Value(kind: pkEmbedded, embedded: x)
|
|
elif compiles(toPreserveHook(x)):
|
|
result = toPreserveHook(x)
|
|
elif T is Bigint:
|
|
result = Value(kind: pkBigInteger, bigint: x)
|
|
elif T is seq[byte]:
|
|
result = Value(kind: pkByteString, bytes: x)
|
|
elif T is array | seq:
|
|
result = Value(kind: pkSequence)
|
|
for v in x.items: result.sequence.add(toPreserve(v, E))
|
|
elif T is bool:
|
|
result = Value(kind: pkBoolean, bool: x)
|
|
elif T is distinct:
|
|
result = toPreserve(x.distinctBase)
|
|
elif T is float:
|
|
result = Value(kind: pkFloat, float: x)
|
|
elif T is float64:
|
|
result = Value(kind: pkDouble, double: x)
|
|
elif T is object | tuple:
|
|
when T.hasCustomPragma(unpreservable): {.fatal: "unpreservable type".}
|
|
elif T.hasCustomPragma(record):
|
|
result = Value(kind: pkRecord)
|
|
for _, f in x.fieldPairs: result.record.add(toPreserve(f))
|
|
result.record.add(symbol(T.getCustomPragmaVal(record)))
|
|
else:
|
|
result = Value(kind: pkDictionary)
|
|
for k, v in x.fieldPairs:
|
|
result[symbol(k, E)] = toPreserve(v, E)
|
|
elif T is Ordinal:
|
|
result = Value(kind: pkSignedInteger, int: x.ord.BiggestInt)
|
|
elif T is ptr | ref:
|
|
if system.`==`(x, nil): result = symbol("null", E)
|
|
else: result = toPreserve(x[])
|
|
elif T is string:
|
|
result = Value(kind: pkString, string: x)
|
|
elif T is SomeInteger:
|
|
result = Value(kind: pkSignedInteger, int: x.BiggestInt)
|
|
else:
|
|
raiseAssert("unpreservable type" & $T)
|
|
|
|
proc toPreserveHook*[T](set: HashSet[T]): Preserve =
|
|
## Hook for preserving ``HashSet``.
|
|
Preserve(kind: pkSet, set: set.map(toPreserve))
|
|
|
|
proc toPreserveHook*[A, B](table: Table[A, B]|TableRef[A, B]): Preserve =
|
|
## Hook for preserving ``Table``.
|
|
result = Preserve(kind: pkDictionary, dict: initTable[Preserve, Preserve](table.len))
|
|
for k, v in table.pairs: result.dict.add((toPreserve(k), toPreserve(v), ))
|
|
|
|
proc fromPreserve*[E, T](v: var T; prs: PreserveGen[E]): bool =
|
|
## Inplace version of `preserveTo`. Returns ``true`` on
|
|
## a complete match, otherwise returns ``false``.
|
|
# TODO: {.raises: [].}
|
|
runnableExamples:
|
|
import preserves, preserves/parse
|
|
type Foo {.record: "foo".} = object
|
|
x, y: int
|
|
var foo: Foo
|
|
assert(fromPreserve(foo, parsePreserves("""<foo 1 2>""")))
|
|
assert(foo.x == 1)
|
|
assert(foo.y == 2)
|
|
type Value = PreserveGen[E]
|
|
when T is Value:
|
|
v = prs
|
|
result = true
|
|
elif compiles(fromPreserveHook(v, prs)):
|
|
result = fromPreserveHook(v, prs)
|
|
elif T is Bigint:
|
|
case prs.kind
|
|
of pkSignedInteger:
|
|
v = initBigint(prs.int)
|
|
result = true
|
|
of pkBigInteger:
|
|
v = prs.bigint
|
|
result = true
|
|
else: disard
|
|
elif T is bool:
|
|
if prs.kind == pkBoolean:
|
|
v = prs.bool
|
|
result = true
|
|
elif T is SomeInteger:
|
|
if prs.kind == pkSignedInteger:
|
|
v = T(prs.int)
|
|
result = true
|
|
elif T is float:
|
|
if prs.kind == pkFloat:
|
|
v = prs.float
|
|
result = true
|
|
elif T is seq:
|
|
if T is seq[byte] and prs.kind == pkByteString:
|
|
v = prs.bytes
|
|
result = true
|
|
elif prs.kind == pkSequence:
|
|
v.setLen(prs.len)
|
|
result = true
|
|
for i, e in prs.sequence:
|
|
result = result and fromPreserve(v[i], e)
|
|
elif T is float64:
|
|
case prs.kind
|
|
of pkFloat:
|
|
v = prs.float
|
|
result = true
|
|
of pkDouble:
|
|
v = prs.double
|
|
result = true
|
|
elif T is object | tuple:
|
|
case prs.kind
|
|
of pkRecord:
|
|
when T.hasCustomPragma(record):
|
|
if prs.record[prs.record.high].isSymbol T.getCustomPragmaVal(record):
|
|
result = true
|
|
var i = 0
|
|
for fname, field in v.fieldPairs:
|
|
if not result or (i == prs.record.high): break
|
|
result = result and fromPreserve(field, prs.record[i])
|
|
inc(i)
|
|
result = result and (i == prs.record.high) # arity equivalence check=
|
|
of pkDictionary:
|
|
result = true
|
|
var fieldCount = 0
|
|
for key, val in v.fieldPairs:
|
|
inc fieldCount
|
|
for (pk, pv) in prs.dict.items:
|
|
var sym = symbol(key, E)
|
|
if sym == pk:
|
|
result = result and fromPreserve(val, pv)
|
|
break
|
|
result = result and prs.dict.len == fieldCount
|
|
else: discard
|
|
elif T is Ordinal | SomeInteger:
|
|
if prs.kind == pkSignedInteger:
|
|
v = (T)prs.int
|
|
result = true
|
|
elif T is ref:
|
|
if prs != symbol("null", E):
|
|
new v
|
|
result = fromPreserve(v[], prs)
|
|
elif T is string:
|
|
if prs.kind == pkString:
|
|
v = prs.string
|
|
result = true
|
|
elif T is distinct:
|
|
result = fromPreserve(result.distinctBase, prs)
|
|
else:
|
|
raiseAssert("no conversion of type Preserve to " & $T)
|
|
if not result: reset v
|
|
|
|
proc preserveTo*[E](prs: PreserveGen[E]; T: typedesc): Option[T] =
|
|
## Reverse of `toPreserve`.
|
|
##
|
|
# TODO: {.raises: [].}
|
|
runnableExamples:
|
|
import std/options, preserves, preserves/parse
|
|
type Foo {.record: "foo".} = object
|
|
x, y: int
|
|
|
|
assert(parsePreserves("""<foo "abc">""").preserveTo(Foo).isNone)
|
|
assert(parsePreserves("""<bar 1 2>""").preserveTo(Foo).isNone)
|
|
assert(parsePreserves("""<foo 1 2>""").preserveTo(Foo).isSome)
|
|
var v: T
|
|
if fromPreserve(v, prs):
|
|
result = some(move v)
|
|
|
|
proc fromPreserveHook*[A,B](t: var Table[A,B]|TableRef[A,B]; prs: Preserve): bool =
|
|
if prs.isDictionary:
|
|
for k, v in prs.pairs:
|
|
t[preserveTo(k, A)] = preserveTo(k, B)
|
|
result = true
|
|
|
|
proc concat[E](result: var string; prs: PreserveGen[E]) =
|
|
case prs.kind:
|
|
of pkBoolean:
|
|
case prs.bool
|
|
of false: result.add "#f"
|
|
of true: result.add "#t"
|
|
of pkFloat:
|
|
result.add($prs.float & "f")
|
|
of pkDouble:
|
|
result.add $prs.double
|
|
of pkSignedInteger:
|
|
result.add $prs.int
|
|
of pkBigInteger:
|
|
result.add $prs.bigint
|
|
of pkString:
|
|
result.add escapeJson(prs.string)
|
|
of pkByteString:
|
|
for b in prs.bytes:
|
|
if b.char notin {'\20'..'\21', '#'..'[', ']'..'~'}:
|
|
result.add("#[") #]#
|
|
result.add(base64.encode(prs.bytes))
|
|
result.add(']')
|
|
return
|
|
result.add("#\"")
|
|
result.add(cast[string](prs.bytes))
|
|
result.add('"')
|
|
of pkSymbol:
|
|
result.add(escapeJsonUnquoted(prs.symbol))
|
|
of pkRecord:
|
|
assert(prs.record.len > 0)
|
|
result.add('<')
|
|
result.concat(prs.record[prs.record.high])
|
|
for i in 0..<prs.record.high:
|
|
result.add(' ')
|
|
result.concat(prs.record[i])
|
|
result.add('>')
|
|
of pkSequence:
|
|
result.add('[')
|
|
for i, val in prs.sequence:
|
|
if i > 0:
|
|
result.add(' ')
|
|
result.concat(val)
|
|
result.add(']')
|
|
of pkSet:
|
|
result.add("#{")
|
|
for val in prs.set.items:
|
|
result.concat(val)
|
|
result.add(' ')
|
|
if prs.set.len > 1:
|
|
result.setLen(result.high)
|
|
result.add('}')
|
|
of pkDictionary:
|
|
result.add('{')
|
|
var i = 0
|
|
for (key, value) in prs.dict.items:
|
|
if i > 0:
|
|
result.add(' ')
|
|
result.concat(key)
|
|
result.add(": ")
|
|
result.concat(value)
|
|
inc i
|
|
result.add('}')
|
|
of pkEmbedded:
|
|
result.add("#!")
|
|
when E is void:
|
|
result.add("#f")
|
|
else:
|
|
result.add($prs.embedded)
|
|
|
|
proc `$`*[E](prs: PreserveGen[E]): string = concat(result, prs)
|
|
## Generate the textual representation of ``prs``.
|