588 lines
17 KiB
Nim
588 lines
17 KiB
Nim
# SPDX-License-Identifier: ISC
|
|
|
|
import base64, endians, json, hashes, sets, streams, tables
|
|
import bigints
|
|
|
|
type
|
|
PreserveKind* = enum
|
|
pkBoolean, pkFloat, pkDouble, pkSignedInteger, pkBigInteger, pkString, pkByteString,
|
|
pkSymbol, pkRecord, pkSequence, pkSet, pkDictionary, pkEmbedded
|
|
|
|
Preserve* {.acyclic.} = object
|
|
## Type that stores a Preserves value.
|
|
case kind*: PreserveKind
|
|
of pkBoolean:
|
|
bool*: bool
|
|
of pkFloat:
|
|
float*: float32
|
|
of pkDouble:
|
|
double*: float64
|
|
of pkSignedInteger:
|
|
int*: BiggestInt
|
|
of pkBigInteger:
|
|
bigint*: BigInt
|
|
of pkString:
|
|
string*: string
|
|
of pkByteString:
|
|
bytes*: seq[byte]
|
|
of pkSymbol:
|
|
symbol*: string
|
|
of pkRecord:
|
|
record*: seq[Preserve] # record[0] is the label
|
|
of pkSequence:
|
|
sequence*: seq[Preserve]
|
|
of pkSet:
|
|
set*: HashSet[Preserve]
|
|
of pkDictionary:
|
|
dict*: Table[Preserve, Preserve]
|
|
of pkEmbedded:
|
|
embedded*: pointer
|
|
|
|
proc `<`(x, y: string | seq[byte]): bool =
|
|
for i in 0 .. min(x.high, y.high):
|
|
if x[i] < y[i]:
|
|
return true
|
|
x.len < y.len
|
|
|
|
proc `<`*(x, y: Preserve): bool =
|
|
if x.kind != y.kind:
|
|
if x.kind == pkSignedInteger and y.kind == pkBigInteger:
|
|
result = x.int.initBigInt < y.bigint
|
|
elif x.kind == pkBigInteger and y.kind == pkSignedInteger:
|
|
result = x.bigint < y.int.initBigInt
|
|
else:
|
|
result = x.kind < y.kind
|
|
else:
|
|
case x.kind
|
|
of pkBoolean:
|
|
result = (not x.bool) and y.bool
|
|
of pkSignedInteger:
|
|
result = x.int < y.int
|
|
of pkBigInteger:
|
|
result = x.bigint < y.bigint
|
|
of pkString:
|
|
result = x.string < y.string
|
|
of pkByteString:
|
|
result = x.bytes < y.bytes
|
|
of pkSymbol:
|
|
result = x.symbol < y.symbol
|
|
else:
|
|
discard
|
|
|
|
proc hash*(prs: Preserve): Hash =
|
|
var h = hash(prs.kind.int)
|
|
case prs.kind
|
|
of pkBoolean:
|
|
h = h !& hash(prs.bool)
|
|
of pkFloat:
|
|
h = h !& hash(prs.float)
|
|
of pkDouble:
|
|
h = h !& hash(prs.double)
|
|
of pkSignedInteger:
|
|
h = h !& hash(prs.int)
|
|
of pkBigInteger:
|
|
h = h !& hash(prs.bigint.flags)
|
|
h = h !& hash(prs.bigint)
|
|
of pkString:
|
|
h = h !& hash(prs.string)
|
|
of pkByteString:
|
|
h = h !& hash(prs.bytes)
|
|
of pkSymbol:
|
|
h = h !& hash(prs.symbol)
|
|
of pkRecord:
|
|
for val in prs.record:
|
|
h = h !& hash(val)
|
|
of pkSequence:
|
|
for val in prs.sequence:
|
|
h = h !& hash(val)
|
|
of pkSet:
|
|
for val in prs.set.items:
|
|
h = h !& hash(val)
|
|
of pkDictionary:
|
|
for (key, val) in prs.dict.pairs:
|
|
h = h !& hash(val)
|
|
of pkEmbedded:
|
|
h = h !& hash(prs.embedded)
|
|
!$h
|
|
|
|
proc `==`*(x, y: Preserve): bool =
|
|
if x.kind == y.kind:
|
|
case x.kind
|
|
of pkBoolean:
|
|
result = x.bool == y.bool
|
|
of pkFloat:
|
|
result = x.float == y.float
|
|
of pkDouble:
|
|
result = x.double == y.double
|
|
of pkSignedInteger:
|
|
result = x.int == y.int
|
|
of pkBigInteger:
|
|
result = x.bigint == y.bigint
|
|
of pkString:
|
|
result = x.string == y.string
|
|
of pkByteString:
|
|
result = x.bytes == y.bytes
|
|
of pkSymbol:
|
|
result = x.symbol == y.symbol
|
|
of pkRecord:
|
|
for i, val in x.record:
|
|
if y.record[i] != val: return false
|
|
result = true
|
|
of pkSequence:
|
|
for i, val in x.sequence:
|
|
if y.sequence[i] != val: return false
|
|
result = true
|
|
of pkSet:
|
|
for val in x.set.items:
|
|
if not y.set.contains(val): return false
|
|
for val in y.set.items:
|
|
if not x.set.contains(val): return false
|
|
result = true
|
|
of pkDictionary:
|
|
for (key, val) in x.dict.pairs:
|
|
if y.dict[key] != val: return false
|
|
result = true
|
|
of pkEmbedded:
|
|
result = x.embedded == y.embedded
|
|
|
|
proc `$`*(prs: Preserve): string =
|
|
case prs.kind:
|
|
of pkBoolean:
|
|
case prs.bool
|
|
of false: result = "#f"
|
|
of true: result = "#t"
|
|
of pkFloat:
|
|
result = $prs.float & "f"
|
|
of pkDouble:
|
|
result = $prs.double
|
|
of pkSignedInteger:
|
|
result = $prs.int
|
|
of pkBigInteger:
|
|
result = $prs.bigint
|
|
of pkString:
|
|
result = escapeJson(prs.string)
|
|
of pkByteString:
|
|
result.add("#[")
|
|
result.add(base64.encode(prs.bytes))
|
|
result.add(']')
|
|
of pkSymbol:
|
|
result.add(escapeJsonUnquoted(prs.symbol))
|
|
of pkRecord:
|
|
result.add('<')
|
|
for val in prs.record:
|
|
result.add(' ')
|
|
result.add($val)
|
|
result.add('>')
|
|
of pkSequence:
|
|
result.add('[')
|
|
for i, val in prs.sequence:
|
|
if i > 0:
|
|
result.add(' ')
|
|
result.add($val)
|
|
result.add(']')
|
|
of pkSet:
|
|
result.add("#{")
|
|
for val in prs.set.items:
|
|
result.add($val)
|
|
result.add(' ')
|
|
if result.len > 1:
|
|
result.setLen(result.high)
|
|
result.add('}')
|
|
of pkDictionary:
|
|
result.add('{')
|
|
for (key, value) in prs.dict.pairs:
|
|
result.add($key)
|
|
result.add(": ")
|
|
result.add($value)
|
|
result.add(' ')
|
|
if result.len > 1:
|
|
result.setLen(result.high)
|
|
result.add('}')
|
|
of pkEmbedded:
|
|
result.add(prs.embedded.repr)
|
|
|
|
proc isNamedTuple(T: typedesc): bool {.magic: "TypeTrait".}
|
|
proc distinctBase(T: typedesc): typedesc {.magic: "TypeTrait".}
|
|
template distinctBase[T](a: T): untyped = distinctBase(type(a))(a)
|
|
|
|
proc symbol*(s: string): Preserve {.inline.} =
|
|
## Symbol constructor.
|
|
Preserve(kind: pkSymbol, symbol: s)
|
|
|
|
proc initRecord*(label: Preserve, args: varargs[Preserve]): Preserve =
|
|
## Record constructor.
|
|
result = Preserve(kind: pkRecord,
|
|
record: newSeqOfCap[Preserve](1+args.len))
|
|
result.record.add(label)
|
|
for arg in args: result.record.add(arg)
|
|
|
|
proc initRecord*(label: string, args: varargs[Preserve]): Preserve {.inline.} =
|
|
## Record constructor that converts ``label`` to a symbol.
|
|
initRecord(symbol(label), args)
|
|
|
|
proc label*(prs: Preserve): Preserve {.inline.} =
|
|
## Return the label of a record value.
|
|
prs.record[0]
|
|
|
|
proc arity*(prs: Preserve): int {.inline.} =
|
|
## Return the number of fields in a record value.
|
|
pred(prs.record.len)
|
|
|
|
proc fields*(prs: Preserve): seq[Preserve] {.inline.} =
|
|
## Return the fields of a record value.
|
|
prs.record[1..prs.record.high]
|
|
|
|
iterator fields*(prs: Preserve): Preserve =
|
|
## Iterate the fields of a record value.
|
|
for i in 1..prs.record.high: yield prs.record[i]
|
|
|
|
proc writeVarint(s: Stream; n: int) =
|
|
var n = n
|
|
while true:
|
|
let c = int8(n and 0x7f)
|
|
n = n shr 7
|
|
if n == 0:
|
|
s.write((char)c.char)
|
|
break
|
|
else:
|
|
s.write((char)c or 0x80)
|
|
|
|
proc readVarint(s: Stream): int =
|
|
var shift: int
|
|
while shift < (9*8):
|
|
let c = s.readChar.int
|
|
result = result or ((c and 0x7f) shl shift)
|
|
if (c and 0x80) == 0:
|
|
break
|
|
shift.inc 7
|
|
|
|
proc write*(str: Stream; prs: Preserve) =
|
|
case prs.kind:
|
|
of pkBoolean:
|
|
case prs.bool
|
|
of false: str.write(0x80'u8)
|
|
of true: str.write(0x81'u8)
|
|
of pkFloat:
|
|
str.write(0x82'u8)
|
|
when system.cpuEndian == bigEndian:
|
|
str.write(prs.float)
|
|
else:
|
|
var be: float32
|
|
swapEndian32(be.addr, prs.float.unsafeAddr)
|
|
str.write(be)
|
|
of pkDouble:
|
|
str.write(0x83'u8)
|
|
when system.cpuEndian == bigEndian:
|
|
str.write(prs.double)
|
|
else:
|
|
var be: float64
|
|
swapEndian64(be.addr, prs.double.unsafeAddr)
|
|
str.write(be)
|
|
of pkSignedInteger:
|
|
if (-3 <= prs.int) and (prs.int <= 12):
|
|
str.write(0x90'i8 or int8(if prs.int < 0: prs.int + 16 else: prs.int))
|
|
else:
|
|
var bitCount = 1'u8
|
|
if prs.int < 0:
|
|
while ((not prs.int) shr bitCount) != 0:
|
|
inc(bitCount)
|
|
else:
|
|
while (prs.int shr bitCount) != 0:
|
|
inc(bitCount)
|
|
var byteCount = (bitCount + 8) div 8
|
|
str.write(0xa0'u8 or (byteCount - 1))
|
|
proc write(n: uint8; i: BiggestInt) =
|
|
if n > 0:
|
|
write(n.pred, i shr 8)
|
|
str.write(i.uint8)
|
|
write(byteCount, prs.int)
|
|
of pkBigInteger:
|
|
doAssert(Negative notin prs.bigint.flags, "negative big integers not implemented")
|
|
var bytes = newSeqOfCap[uint8](prs.bigint.limbs.len * 4)
|
|
var begun = false
|
|
for i in countdown(prs.bigint.limbs.high, 0):
|
|
let limb = prs.bigint.limbs[i]
|
|
for j in countdown(24, 0, 8):
|
|
let b = uint8(limb shr j)
|
|
begun = begun or (b != 0)
|
|
if begun:
|
|
bytes.add(b)
|
|
if bytes.len <= 16:
|
|
str.write(0xa0'u8 or bytes.high.uint8)
|
|
else:
|
|
str.write(0xb0'u8)
|
|
str.writeVarint(bytes.len)
|
|
str.write(cast[string](bytes))
|
|
of pkString:
|
|
str.write(0xb1'u8)
|
|
str.writeVarint(prs.string.len)
|
|
str.write(prs.string)
|
|
of pkByteString:
|
|
str.write(0xb2'u8)
|
|
str.writeVarint(prs.bytes.len)
|
|
str.write(prs.bytes)
|
|
of pkSymbol:
|
|
str.write(0xb3'u8)
|
|
str.writeVarint(prs.symbol.len)
|
|
str.write(prs.symbol)
|
|
of pkRecord:
|
|
str.write(0xb4'u8)
|
|
for val in prs.record:
|
|
str.write(val)
|
|
str.write(0x84'u8)
|
|
of pkSequence:
|
|
str.write(0xb5'u8)
|
|
for e in prs.sequence:
|
|
str.write(e)
|
|
str.write(0x84'u8)
|
|
of pkSet:
|
|
str.write(0xb6'u8)
|
|
for val in prs.set.items:
|
|
str.write(val)
|
|
str.write(0x84'u8)
|
|
of pkDictionary:
|
|
str.write(0xb7'u8)
|
|
for (key, value) in prs.dict.pairs:
|
|
str.write(key)
|
|
str.write(value)
|
|
str.write(0x84'u8)
|
|
of pkEmbedded:
|
|
str.write(0x86'u8)
|
|
raiseAssert("binary representation of embedded values is undefined")
|
|
|
|
proc parsePreserve*(s: Stream): Preserve =
|
|
proc assertStream(check: bool) =
|
|
if not check:
|
|
raise newException(ValueError, "invalid Preserves stream")
|
|
const endMarker = 0x84
|
|
let tag = s.readUint8()
|
|
case tag
|
|
of 0x80: result = Preserve(kind: pkBoolean, bool: false)
|
|
of 0x81: result = Preserve(kind: pkBoolean, bool: true)
|
|
of 0x82:
|
|
when system.cpuEndian == bigEndian:
|
|
result = Preserve(kind: pkFloat, float: s.readFloat32())
|
|
else:
|
|
result = Preserve(kind: pkFloat)
|
|
var be = s.readFloat32()
|
|
swapEndian32(result.float.addr, be.addr)
|
|
of 0x83:
|
|
when system.cpuEndian == bigEndian:
|
|
result = Preserve(kind: pkDouble, double: s.readFloat64())
|
|
else:
|
|
result = Preserve(kind: pkDouble)
|
|
var be = s.readFloat64()
|
|
swapEndian64(result.double.addr, be.addr)
|
|
of 0x84:
|
|
assertStream(false)
|
|
of 0xb1:
|
|
result = Preserve(kind: pkString)
|
|
let len = s.readVarint()
|
|
result.string = s.readStr(len)
|
|
of 0xb2:
|
|
result = Preserve(kind: pkByteString)
|
|
let len = s.readVarint()
|
|
result.bytes = cast[seq[byte]](s.readStr(len))
|
|
of 0xb3:
|
|
let len = s.readVarint()
|
|
result = symbol(s.readStr(len))
|
|
of 0xb4:
|
|
result = Preserve(kind: pkRecord)
|
|
while s.peekUint8() != endMarker:
|
|
result.record.add(s.parsePreserve())
|
|
discard s.readUint8()
|
|
assertStream(result.record.len > 0)
|
|
of 0xb5:
|
|
result = Preserve(kind: pkSequence)
|
|
while s.peekUint8() != endMarker:
|
|
result.sequence.add(s.parsePreserve())
|
|
discard s.readUint8()
|
|
of 0xb6:
|
|
result = Preserve(kind: pkSet)
|
|
while s.peekUint8() != endMarker:
|
|
result.set.incl(s.parsePreserve())
|
|
discard s.readUint8()
|
|
of 0xb7:
|
|
result = Preserve(kind: pkDictionary)
|
|
while s.peekUint8() != endMarker:
|
|
let key = s.parsePreserve()
|
|
let val = s.parsePreserve()
|
|
result.dict[key] = val
|
|
discard s.readUint8()
|
|
of 0xb0:
|
|
let len = s.readVarint()
|
|
result = Preserve(kind: pkBigInteger)
|
|
for _ in 1..len:
|
|
result.bigint = (result.bigint shl 8) + s.readUint8().int32
|
|
else:
|
|
case 0xf0 and tag
|
|
of 0x90:
|
|
var n = tag.BiggestInt
|
|
result = Preserve(kind: pkSignedInteger,
|
|
int: n - (if n > 0x9c: 0xa0 else: 0x90))
|
|
of 0xa0:
|
|
let len = (tag.int and 0x0f) + 1
|
|
if len <= 8:
|
|
result = Preserve(kind: pkSignedInteger, int: s.readUint8().BiggestInt)
|
|
if (result.int and 0x80) != 0: result.int.dec(0x100)
|
|
for i in 1..<len:
|
|
result.int = (result.int shl 8) or s.readUint8().BiggestInt
|
|
else:
|
|
result = Preserve(kind: pkBigInteger)
|
|
for i in 0..<len:
|
|
result.bigint = (result.bigint shl 8) + s.readUint8().int32
|
|
else:
|
|
assertStream(false)
|
|
|
|
proc toPreserveHook*(n: BigInt): Preserve =
|
|
if initBigInt(low(BiggestInt)) < n and n < initBigInt(high(BiggestInt)):
|
|
var tmp: BiggestUint
|
|
for limb in n.limbs:
|
|
tmp = (tmp shl 32) or limb
|
|
if Negative in n.flags:
|
|
tmp = (not tmp) + 1
|
|
result = Preserve(kind: pkSignedInteger, int: cast[BiggestInt](tmp))
|
|
else:
|
|
result = Preserve(kind: pkBigInteger, bigint: n)
|
|
|
|
proc toPreserveHook*(js: JsonNode): Preserve =
|
|
case js.kind
|
|
of JString:
|
|
result = Preserve(kind: pkString, string: js.str)
|
|
of JInt:
|
|
result = Preserve(kind: pkSignedInteger, int: js.num)
|
|
of JFloat:
|
|
result = Preserve(kind: pkDouble, double: js.fnum)
|
|
of JBool:
|
|
result = case js.bval
|
|
of false: symbol"false"
|
|
of true: symbol"true"
|
|
of JNull:
|
|
result = symbol"null"
|
|
of JObject:
|
|
result = Preserve(kind: pkDictionary)
|
|
for key, val in js.fields.pairs:
|
|
result.dict[Preserve(kind: pkString, string: key)] = toPreserveHook(val)
|
|
of JArray:
|
|
result = Preserve(kind: pkSequence,
|
|
sequence: newSeq[Preserve](js.elems.len))
|
|
for i, e in js.elems:
|
|
result.sequence[i] = toPreserveHook(e)
|
|
|
|
proc toPreserve*[T](x: T): Preserve =
|
|
## Serializes `x` to Preserves; uses `toPreserveHook(x: A)` if it's in scope to
|
|
## customize serialization.
|
|
when T is Preserve: result = x
|
|
elif compiles(toPreserveHook(x)):
|
|
result = toPreserveHook(x)
|
|
elif T is array | seq:
|
|
result = Preserve(kind: pkSequence)
|
|
for v in x.items: result.sequence.add(toPreserve(v))
|
|
elif T is bool:
|
|
result = Preserve(kind: pkBoolean, bool: x)
|
|
elif T is distinct:
|
|
result = toPreserve(x.distinctBase)
|
|
elif T is float:
|
|
result = Preserve(kind: pkFloat, float: x)
|
|
elif T is float64:
|
|
result = Preserve(kind: pkDouble, double: x)
|
|
elif T is object:
|
|
result = Preserve(kind: pkDictionary)
|
|
for k, v in x.fieldPairs: result.dict[symbol(k)] = toPreserve(v)
|
|
elif T is Ordinal:
|
|
result = Preserve(kind: pkSignedInteger, int: x.ord.BiggestInt)
|
|
elif T is ptr | ref:
|
|
if system.`==`(x, nil): result = symbol"null"
|
|
else: result = toPreserve(x[])
|
|
elif T is string:
|
|
result = Preserve(kind: pkString, string: x)
|
|
elif T is SomeInteger:
|
|
result = Preserve(kind: pkSignedInteger, int: x.BiggestInt)
|
|
elif T is tuple:
|
|
result = Preserve(kind: pkRecord, record: @[symbol("")])
|
|
for v in x.fields: result.record.add(toPreserve(v))
|
|
else:
|
|
raiseAssert("cannot convert to Preserves: " & $T)
|
|
|
|
proc toJsonHook*(prs: Preserve): JsonNode =
|
|
case prs.kind:
|
|
of pkBoolean:
|
|
result = newJBool(prs.bool)
|
|
of pkFloat:
|
|
result = newJFloat(prs.float)
|
|
of pkDouble:
|
|
result = newJFloat(prs.double)
|
|
of pkSignedInteger:
|
|
result = newJInt(prs.int)
|
|
of pkBigInteger:
|
|
raise newException(ValueError, "cannot convert big integer to JSON")
|
|
of pkString:
|
|
result = newJString(prs.string)
|
|
of pkByteString:
|
|
raise newException(ValueError, "cannot convert bytes to JSON")
|
|
of pkSymbol:
|
|
case prs.symbol
|
|
of "false":
|
|
result = newJBool(false)
|
|
of "true":
|
|
result = newJBool(true)
|
|
of "null":
|
|
result = newJNull()
|
|
else:
|
|
raise newException(ValueError, "cannot convert symbol to JSON")
|
|
of pkRecord:
|
|
raise newException(ValueError, "cannot convert record to JSON")
|
|
of pkSequence:
|
|
result = newJArray()
|
|
for val in prs.sequence:
|
|
result.add(toJsonHook(val))
|
|
of pkSet:
|
|
raise newException(ValueError, "cannot convert set to JSON")
|
|
of pkDictionary:
|
|
result = newJObject()
|
|
for (key, val) in prs.dict.pairs:
|
|
if key.kind != pkString:
|
|
raise newException(ValueError, "cannot convert non-string dictionary key to JSON")
|
|
result[key.string] = toJsonHook(val)
|
|
of pkEmbedded:
|
|
raise newException(ValueError, "cannot convert embedded value to JSON")
|
|
|
|
type Record* = object
|
|
## Type of a preserves record type.
|
|
label*: string
|
|
arity*: Natural
|
|
|
|
proc init*(rec: Record, fields: varargs[Preserve]): Preserve =
|
|
## Initialize a new record value.
|
|
assert(fields.len == rec.arity)
|
|
initRecord(rec.label, fields)
|
|
|
|
proc isClassOf*(rec: Record, val: Preserve): bool =
|
|
## Compare the label and arity of ``val`` to the record type ``rec``.
|
|
if val.kind == pkRecord:
|
|
let label = val.label
|
|
if label.kind == pkSymbol:
|
|
result = label.symbol == rec.label and rec.arity == val.arity
|
|
|
|
proc classOf*(val: Preserve): Record =
|
|
## Derive the ``Record`` type of ``val``.
|
|
if val.kind != pkRecord or val.label.kind == pkSymbol:
|
|
raise newException(ValueError, "cannot derive class of non-record value")
|
|
Record(label: val.label.symbol, arity: val.arity)
|
|
|
|
proc len*(prs: Preserve): int =
|
|
## Return the number of values one level below ``prs``.
|
|
case prs.kind
|
|
of pkRecord: prs.record.len.pred
|
|
of pkSequence: prs.sequence.len
|
|
of pkSet: prs.set.len
|
|
of pkDictionary: prs.dict.len
|
|
else: 0
|
|
|
|
proc `[]`*(prs: Preserve; i: int): Preserve =
|
|
case prs.kind
|
|
of pkRecord: prs.record[succ(i)]
|
|
of pkSequence: prs.sequence[i]
|
|
else:
|
|
raise newException(ValueError, "`[]` is not valid for " & $prs.kind)
|